Problemas con Keyascii - VB-MUNDO

ikki_26 · #1 (**permalink**) 04-10-2005, 15:03:30

Deseo que en mi caja de texto solo escriba MAYUSCULAS, en caso q en el teclado este habilatado o desabilitado el BLOQ MAYUS igual que en mi texto salga mayuscula... Como se hace eso?...

Y tambien lo deseo hacer con numeros que solo me permita en un texto escribir numeros y no caracteres...

Alella · #2 (**permalink**) 04-10-2005, 15:23:39

Hola, que tal.

Esto es para el apartado numérico.

Código:


Dim B As String

Do
   B = InputBox("Introduzca un numero de banco: ")
Loop Until IsNumeric(B)

Esto para el aparatado mayusculas.

Código:

e = InputBox("Introduce el nombre del fichero :" & vbCrLf & vbCrLf, , , 4100, 4400)



e = UCase(e)

Espero que te sirva.

juancarlosavalos · #3 (**permalink**) 04-10-2005, 15:55:40

Cita:

Empezado por ikki_26

Deseo que en mi caja de texto solo escriba MAYUSCULAS, tambien lo deseo hacer con numeros que solo me permita en un texto escribir numeros y no caracteres...

Esto es un ejemplo de lo que puedes hacer mediante el código ascii, tu amoldalo a tus necesidades:

Código:

Private Sub Form_Load()
    Text1.Text = ""
    Text2.Text = ""
    Text3.Text = ""
End Sub

Private Sub Text1_KeyPress(KeyAscii As Integer)
'esto permite solo ingresar letras mayusculas kesascii>=65 and keyascii<=90
'esto solo letras minúsculas KeyAscii >= 97 And KeyAscii <= 122
'esto el retroceso keyascii = 8 y esto el space keyascii = 32
    If (KeyAscii >= 65 And KeyAscii <= 90) Or KeyAscii = 8 Or KeyAscii = 32 Then
    ElseIf (KeyAscii >= 97 And KeyAscii <= 122) Then
        KeyAscii = KeyAscii - 32
    Else
        KeyAscii = 0
        MsgBox "Ingrese una Letra"
        Beep
    End If
End Sub

Private Sub Text2_KeyPress(KeyAscii As Integer)
'estos son numeros KeyAscii >= 48 And KeyAscii <= 57
    If KeyAscii = 8 Or KeyAscii >= 48 And KeyAscii <= 57 Then
    Else
        KeyAscii = 0
        MsgBox "Ingrese un Valor entero positivo", 0, "Validar Dato"
        Beep
    End If
End Sub

Private Sub Text3_KeyPress(KeyAscii As Integer)
'esto es la coma KeyAscii = 44
'esto es el punto KeyAscii = 46
    If KeyAscii = 8 Or KeyAscii = 44 Or KeyAscii = 46 Or (KeyAscii >= 48 And KeyAscii <= 57) Then
    Else
        KeyAscii = 0
        MsgBox "Ingrese un Valor real positivo", 0, "Validar Dato"
        Beep
    End If
End Sub

Private Sub Text3_LostFocus()
On Error Resume Next
    Text3.Text = Format(CDbl(0 & Text3.Text), _
    "#,###,###,##0.00####")
End Sub

ikki_26 · #4 (**permalink**) 05-10-2005, 05:09:20

Muchas gracias amigo te pasaste