Como lo puedo hacer? - VB-MUNDO

ikki_26 · #1 (**permalink**) 08-05-2005, 06:42:33

Como puedo hacer para que cuando se ejecute un programa nose muestre solo se minimize en la barra de herramientas al lado de la HORA y que cuando le de click al icono se muestre el programa por ejemplo:

el icono de mysql cuando le das click derecho salen propiedades le das click alli y se muestra una ventana para hacer modificaciones algo asi se alguien puede asesorarme con eso?

acalanto · #2 (**permalink**) 08-05-2005, 08:25:55

Debes utilizar SystrayIcon para poner la aplicación en la barra de sistema

Pon estás declaraciones en el formulario principal (o en un módulo público si lo prefieres)

Código:

    'DECLARACIONES DE LA API DE WINDOWS
    Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
    Private Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long


    'ESTRUCTURA SYSTRAY
    Private Type NOTIFYICONDATA
        cbSize As Long             'Tamaño de UDT
        hwnd As Long               'Handle de la aplicación
        uId As Long                'No usado
        uFlags As Long             'Semáforo de acciones
        uCallBackMessage As Long   'Intercambio de mensajes
        hIcon As Long              'Icono de la barra
        szTip As String * 64       'ToolTip de la barra
    End Type


    'Constantes de la API
    Private Const NIM_ADD = &H0             'Nuevo Nid
    Private Const NIM_MODIFY = &H1          'Modificar NID
    Private Const NIM_DELETE = &H2          'Borrar NID
    Private Const NIF_MESSAGE = &H1         'NID Válido
    Private Const NIF_ICON = &H2            'Icono NID inválido
    Private Const NIF_TIP = &H4             'ToolTip válido
    Private Const WM_MOUSEMOVE = &H200      'Nuestro mensaje de retorno
    Private Const WM_LBUTTONDOWN = &H201    'Botón izquierdo presionado
    Private Const WM_LBUTTONUP = &H202      'Boton izquierdo liberado
    Private Const WM_LBUTTONDBLCLK = &H203  'Doble click
    Private Const WM_RBUTTONDOWN = &H204    'Botón derecho presionado
    Private Const WM_RBUTTONUP = &H205      'Botón derecho liberado
    Private Const WM_RBUTTONDBLCLK = &H206  'Doble click (Botón derecho)

    Private nid As NOTIFYICONDATA           'UDT Global para las funciones Systray

En el evento Load del formularioprincipal inserta ésto:

Código:

    With nid
        .cbSize = Len(nid)
        .hwnd = Me.hwnd
        .uId = vbNull
        .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
        .uCallBackMessage = WM_MOUSEMOVE
        .hIcon = Me.Icon
        .szTip = "<Etiqueta de texto que se muestra>" & vbNullChar
    End With
    Shell_NotifyIcon NIM_ADD, nid

En el evento Unload esto otro (Para retirar el icono de la barra)

Código:

    With nid
        .cbSize = Len(nid)
        .hwnd = Me.hwnd
        .uId = vbNull
        .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
        .uCallBackMessage = WM_MOUSEMOVE
        .hIcon = Me.Icon
        .szTip = "<Etiqueta de texto que se muestra>"& vbNullChar
    End With
    Shell_NotifyIcon NIM_DELETE, nid

y este código para detectar cuando el ratón pasa por el icono de la barra.

Código:

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
  Dim msg As Long
  If (Me.ScaleMode = vbPixels) Then
    msg = x
  Else
    msg = x / Screen.TwipsPerPixelX
  End If
  'windows 2000, XP
  Select Case Button
    Case 1, WM_LBUTTONDBLCLK   'Mostrar panel de administración
      Me.WindowState = vbNormal
      Call SetForegroundWindow(Me.hwnd)
      Me.Show
    Case 2, WM_RBUTTONUP       'Mostrar menú
      Call SetForegroundWindow(Me.hwnd)
      Me.PopupMenu Me.<nombredelmenú>
    Case WM_LBUTTONUP
  End Select
    'Windows 95 98
  Select Case msg
    Case 513   'Mostrar panel de administración
      Me.WindowState = vbNormal
      Call SetForegroundWindow(Me.hwnd)
      Me.Show
    Case 516
      Call SetForegroundWindow(Me.hwnd)
      Me.PopupMenu Me.<nombredelmenú>
    Case WM_LBUTTONUP
  End Select
End Sub

En el formulario tienes que construir un menú 'no visible' que mostrarás en Me.PopupMenu Me.<nombredelmenú>, en el que lógicamente tendrás que escribir el nombre que tú le hayas dado a dicho menú.

Espero que estás API te resulten de utilidad.

ikki_26 · #3 (**permalink**) 08-05-2005, 22:45:07

Disculpa por no entender muy bien pero me sale el siguiente error

Otra cosita no entiendo con eso de crear un menu?

ESpero me ayudes

acalanto · #4 (**permalink**) 09-05-2005, 06:41:23

Seguramente has puesto las declaraciones en un módulo aparte del formulario principal. En ese caso debes declarar las funciones de API, estructuras de datos y constantes como públicas y no privadas.

Si insertas un menú en el formulario principal, al pulsar el botón derecho del ratón sobre el icono de la barra, te aparecerá como contextual.

Manolillo · #5 (**permalink**) 27-02-2006, 11:22:50

He conseguido mostrar el menú en la barra de herramientas, pero no consigo visualizar el menú emergente... que puede estar pasando?

Manolillo · #6 (**permalink**) 27-02-2006, 11:29:19

Perdón, pero mi post anterior está mal, lo que he conseguido mostrar en la barra de herramientas es el icono, y lo que no consigo ver es el menú...

acalanto · #7 (**permalink**) 27-02-2006, 15:20:08

Pero el menú ¿lo has creado?.

Tiene que crear un menú con el editor y ponerlo como invisible P. Ej.

Código:

Opción_A  <-- ÉSTA VISIBLE; APARECERÁ EN EL MENÚ DEL FORM
    Sub_opción A1
    Sub_opción A2
Opción_B  <-- ÉSTA VISIBLE; APARECERÁ EN EL MENÚ DEL FORM
    Sub_opción B1
    Sub_opción B2
    Sub_opción B3
    Sub_opción B2
Opción_C  <-- ÉSTA INVISIBLE; NO APARECERÁ EN EL MENÚ DEL FORM
    Sub_opción C1
    Sub_opción C2
    Sub_opción C3
    Sub_opción C2

Pero si aparecerá cuando el método Form_MouseMove detecte la pulsación del botón derecho sobre el Tray-Icon y ejecuta la sentencia

Código:

Me.PopupMenu Me.Opción_C

Entonces se mostrará el menú emergente con las opciones contenidas.

NOTA: Opción_C es el nombre de la CLAVE y no el TÍTULO del menú.

Manolillo · #8 (**permalink**) 28-02-2006, 08:03:00

Estoy colocando el código del Form_MouseMove en el mdi principal y nada, tambien he probado a colocarlo en otros formularios, pero no consigo que se me muestre el menú, el cual tiene la siguiente estructura:

MenuIcono---------->Invisible
......Abrir Aplicacion-->Visible
......Cerrar Aplicacion-->Visible

En el código del Form_MouseMove le pongo esto:

Código:

Me.PopupMenu Me.MenuIcono

No se que es lo que estoy haciendo mal, cuando pulso el botón derecho sobre el icono, nada, no hace nada.

acalanto · #9 (**permalink**) 28-02-2006, 08:25:28

Depura con la tecla F8 el método Mouse_Move y determina que valores recoge Button y Msg.

Asegurate que la clave del menú que pretendes mostrar sea MenuIcono

Manolillo · #10 (**permalink**) 28-02-2006, 08:32:17

la clave si que es MenuIcono;
Ni siquiera entra en Form_MouseMove, estoy muy perdido...